No videos at all in game

[SewerynV]

So i installed Indeo® 3.2, 4.5, and 5.11 Codecs and Support Files developer version, newest directx 9.0c 2010, microsoft visual c+ redistributable from 2005 to 2015 for x60 and x64 bit versions ( 2005, 2008 9.2/9.3, 2010, 2012,2013, 2015 ).
I can play the movies in my windows media player and they play flawlessly.
But i cannot see them in game.
I have no idea if i should do something else.
Any info would be appreciated.
Thanks,
Sew

[menocheck]

You can try the following:
Open a 'command prompt' using a rightclick, select, 'Run as Administrtor'
type: cd C:\Windows\SysWOW64 - press enter
type: regsvr32 ir50_32.dll - press enter

Worked for a friend on Windows 10

[Nightangel]

You can try the following:
Open a 'command prompt' using a rightclick, select, 'Run as Administrtor'
type: cd C:\Windows\SysWOW64 - press enter
type: regsvr32 ir50_32.dll - press enter

Worked for a friend on Windows 10

Thank you for this extremely valuable tip.
This guide helps me after every Windows update.

Only note: on Windows 10 you have to do this in the Windows Power Shell (Administrator).

[EPW]

Thank you for the fix

[El_Cid]

I also got it to work by installing the K-Lite codecs (by installing the K-Lite player). I'm using the GOG version which by default has no in-game wonder movies or game music, but I fixed all that with the K-Lite player as per this thread on GOG here:

https://www.gog.com/forum/call_to_power_2/installing_klite_codec_pack_can_play_videos

[Ninjaboy042099]

I wrote a batch script to get this working, for those who don't have it working already:

@echo off
setlocal

rem Check for admin privileges
net session >nul 2>&1
if %ERRORLEVEL% NEQ 0 (
    echo Error: This script requires administrator privileges.
    echo Please right-click the script and select "Run as administrator".
    echo Press any key or CTRL+C to exit...
    pause > nul
    goto :EOF
)

echo ================================================
echo WARNING: SECURITY NOTICE
echo ================================================
echo The Indeo codec is an older video codec that has known security
echo vulnerabilities. Microsoft has removed native support in newer
echo Windows versions for security reasons.
echo.
echo Only install this codec if you accept this risk.
echo.
echo Press any key to continue or CTRL+C to cancel...
pause > nul

echo Checking system for Indeo video codec components...

rem Check if SysWOW64 directory exists
if not exist "%SystemRoot%\SysWOW64" (
    echo Error: This system appears to be running 32-bit Windows.
    echo This script is designed for 64-bit Windows systems only.
    echo Press any key or CTRL+C to exit...
    pause > nul
    goto :EOF
)

rem Check if regsvr32 exists
if not exist "%SystemRoot%\System32\regsvr32.exe" (
    if not exist "%SystemRoot%\SysWOW64\regsvr32.exe" (
        echo Error: regsvr32 utility not found.
        if exist "%SystemRoot%\SysWOW64\ir50_32.dll" (
            echo The Indeo codec DLL file ir50_32.dll is present, but cannot be registered.
            echo To register the DLL manually in Windows 11:
            echo 1. Click Start, type "cmd", right-click on "Command Prompt" and select "Run as administrator"
            echo 2. In the command prompt window, type: cd %%SystemRoot%%\SysWOW64 and hit enter
            echo 3. In the command prompt window, type: regsvr32 ir50_32.dll and hit enter
            echo You should see a pop-up that the DLL was registered successfully. If not, please reach out for help within the Discord.
        ) else (
            echo The Indeo codec DLL file ir50_32.dll is also missing.
        )
        echo Press any key or CTRL+C to exit...
        pause > nul
        goto :EOF
    )
)

rem Check if ir50_32.dll exists
if not exist "%SystemRoot%\SysWOW64\ir50_32.dll" (
    echo Error: ir50_32.dll not found in %%SystemRoot%%\SysWOW64.
    echo The Indeo video codec DLL file is missing.
    echo regsvr32 exists but cannot register a missing DLL.
    echo Press any key or CTRL+C to exit...
    pause > nul
    goto :EOF
)

rem If all checks pass, register the DLL
echo All components found. Registering Indeo video codec...

cd /d %SystemRoot%\SysWOW64
regsvr32 ir50_32.dll
if %ERRORLEVEL% NEQ 0 (
    echo Error: Failed to register ir50_32.dll. Error code: %ERRORLEVEL%
    echo Possible issues:
    echo - File may be corrupted
    echo - Windows security policy may be blocking registration
    echo - Another system issue is preventing registration
    echo Press any key or CTRL+C to exit...
    pause > nul
    exit /b %ERRORLEVEL%
) else (
    echo Successfully registered ir50_32.dll
)

echo Done. Press any button to continue.

pause > nul
exit /b %ERRORLEVEL%

exit /b 0​

Paste that code into a file called video.bat and then right-click and run it as administrator. It will register the DLL for you if it exists on your system. I would upload video.bat myself, but it was (rightfully) blocked.