Looking for a custom mod

[waltergr]

Don't think it's out there...at least I haven't seen it. But, here's what I want - maybe somebody could help me find it?

When a city is captured, you have 3 choices:
1. Expand your empire (control city)
2. Bloodbath (level city, decimate population - lowers regard)
3. Move population (level city, but population "immigrates" to your empire.)

Choice #1 is what the game currently does.

Choice #2 would give you gold (in the "sell" value of any buildings), and improvement funds (in the value of any tile improvements). However, it would also lower your regard among other nations.

Choice #3 wouldn't give you any gold/improvement funds - but neither would it affect your regard among the other nations. The city and any tile improvements would disappear. The population would be "absorbed" by your empire. At least the closest city, but preferably spread out among all your cities.

I feel this better represents the real outcome of warfare. You either take over the territory, destroy it and kill the population, or force the population to move to your cities.

Can anybody help me with this?

[Pedrunn]

Matin Guhmann already made a Slic wich includes choice 1 and 2. Take a look at his website.

[Immortal Wombat]

Yeah, Martin did most of this: http://apolyton.net/forums/showthrea...&threadid=2742

Here is the code. To get it to work, bung it into a SLIC file such as script.slc or scenario.slc.

///////////////////////////////////////////////////////////////////////////////////////////
//New City Capture Option for CTP2 (MG_KillCityOption.slc) v. 1.0 by Martin Gühmann      //
///////////////////////////////////////////////////////////////////////////////////////////
//This script file adds now the possiblity for the human player to eleminate a city after//
//capturing. It gives per pop the player 500 gold and 500 PW. But unfortunatly there is  //
//also a regard loss concerning other nations.                                           //
///////////////////////////////////////////////////////////////////////////////////////////
//To install this script just unzip the *zip file into your default CTP2 folder and open //
//the file script.slc in your ..\ctp2_data\default\gamedata\ folder and add to the end of//
//this file the line #include "MG_KillCityOption.slc". Afterwards go to your             //
//..\ctp2_data\english\gamedata\ folder (if your using the German version it is of course//
//the ..\ctp2_data\german\gamedata\ folder) and open there the file string.txt and add   //
//the line import "MG_KillCityOption.txt". If you want to you use these files with one of//
//the mods you have to look for files with the according prefix like MM2_ for MedPack2 or//
//CRA_ for Cradle or APOL_ for Apolyton Pack or APOLU_ for the extra large Apolyton Pack //
//map version.                                                                           //
///////////////////////////////////////////////////////////////////////////////////////////

city_t DestroyCity;

HandleEvent(CaptureCity) 'MG_KillCityOption' post {
	if (city[0].population>1) {
		if(IsHumanPlayer(g.player)){
			if(CityIsValid(city[0])) {
				message(g.player, 'DestroyCityMSG');
			}
		}
	}
}

AlertBox 'DestroyCityMSG' {
int_t i;
int_t MGPw;
Title(ID_DESTROY_CITY_TITLE);
Text(ID_DESTROY_CITY);
//MessageType("MILITARY");
DestroyCity = city[0];
Show();
	Button(ID_EXTEND_EMPIRE) {
		Kill();  
	}
	Button(ID_BLOODBATH) {
		if(CityIsValid(city[0])) {
			AddGold(player[0], (city[0].population*500));
			MGPw = player[0].publicworkslevel;
			MGPw = MGPw + (city[0].population*500);
			setPW(player[0], MGPw);
			ChangeGlobalRegard(player[0], -50, ID_BLOODBATH, 50);
			for (i=city[0].population; i>=0; i=i-1){
				if(CityIsValid(city[0])) {
					Event: KillPop(city[0]);
				}
			}
			Kill(); 
		}
	}  
                 //***
}

To insert the third option, then at the point where I marked //***, replace it with:

Button(ID_EVACUATE) {
	int_t j;
	city_T	tmpCity;
	if(CityIsValid(city[0])){
		for (i=city[0].population; i>=0; i=i-1){
			if(CityIsValid(city[0])) {
				Event: KillPop(city[0]);
				j = random(PlayerCityCount(g.player));
				GetCityByIndex(g.player, j, tmpCity);
				AddPops(tmpCity, 1);
			}
		}
	}
	Kill();
}

Then open scen_str.txt and add the following lines:

DESTROY_CITY_TITLE "Capture or destroy city?"
DESTROY_CITY "{player[0].leader_name#SIR_CAP}, we conquered the city {city[0].name}. Thousands of citizens await your decision with fear: Either you annex the city {city[0].name} into the empire or you pillage it, sack it and cause a bloodbath under the civil population. But note a bloodbath will lower our regard. Alternatively you can move the citizens to our existing cities, and raze the city to the ground."
EXTEND_EMPIRE "Extend Empire"
BLOODBATH "Bloodbath"
EVACUATE "Disband"


The third option now distributes the population of that city randomly over your empire.

[Martin Gühmann]

something to add for my GoodMod. I should reincrease the regard cost by the way. I hope I can finish the AI files before Chrismas. Still some goals are left to add them to goals.txt and strategies.txt. But that is not very much. To add player1's modifications to my strategies.txt needed a little bit longer but that is done. I only need to add some goals that covers some forgotten orders.

-Martin

[waltergr]

Thanks all

Special thanks to Martin for the good work!

I guess I'm gonna havta check out this forum more often.

Have a happy holiday.

[player1]

Originally posted by Martin Gühmann
something to add for my GoodMod. I should reincrease the regard cost by the way. I hope I can finish the AI files before Chrismas. Still some goals are left to add them to goals.txt and strategies.txt. But that is not very much. To add player1's modifications to my strategies.txt needed a little bit longer but that is done. I only need to add some goals that covers some forgotten orders.

-Martin

If you have any problems with AI I made just ask me by PM.
Then post a thread in CTP2/mod and I will explain.

You can ask me about some of "strategic" decisions for various AI flags also.

[Martin Gühmann]

I found a small bug in your code Ben:

 j = random(PlayerCityCount(g.player));

The effect of this one is that the just conquered city is not killed, but this one will do the job as we have to exclude the last city from player city count:

 j = random(PlayerCityCount(g.player)-1);

By the way GoodMod v0.98 is know in the playtest phase I guess I can post it soon.

-Martin

[Martin Gühmann]

OK the New City Kill Option for CTP2 version 1.3 is now available on my homepage. But anyway I would play the whole GoodMod.

Merry Christmas

-Martin.