@BEGINEVENTS

@IF
NOSCHISM
defender=ANYBODY
@THEN
@ENDIF

@IF
TURN
turn=9
@THEN
TEXT
^^=WINTER!=
^
^^Save the game under the name EU.sav (important!), 
^^Run the program EUROPE.bat, 
^^Select Load season files (option 2) - Winter 1940-41. 
^^Then return to the game and reload EU.sav 
ENDTEXT
@ENDIF

@IF
TURN
turn=2
@THEN
TEXT
^^=APRIL 1940=
^
^The Second World War in Europe has been lasted already 7 months. 
^The Nazi and Soviet war machines have swallowed Poland and Baltic 
^countries. Finland narrowly managed to save her independence during 
^the terrible Winter War. Great Britain and France have reacted 
^by declaring war on Germany, but refused to confront the Soviet Union.
^During winter both opposing armies in Western Front are preparing
^for decisive summer battles..       
ENDTEXT
PLAYWAVEFILE
THEME.WAV
@ENDIF

@IF
TURN
turn=3
@THEN
TEXT
^On May 10th 1940 German Wehrmacht invaded Belgium, Luxembourg, 
^Netherlands and France. Response to this Allied armies started 
^move into Low Countries. The Battle of France had begun.
^The same day Winston Churchill became Prime Minister of Great 
^Britain following resignation of Neville Chamberlain... 
ENDTEXT
PLAYWAVEFILE
THEME.WAV
@ENDIF

@IF
CITYTAKEN
city=Lille
attacker=Axis
defender=France
@THEN
TEXT
^German Army Group "A" penetrated French front and started to drive
^toward the sea. 
^The main idea of the offensive was first proposed by general 
^Erich von Manstein. German general staff was against the plan 
^in the beginning but Manstein managed to get Hitler on his side. 
ENDTEXT
JUSTONCE
@ENDIF

@IF
TURN
turn=3
@THEN
TEXT
^"You ask 'what is our aim?' I can answer in one word - 'victory'! 
^Victory at all costs! Victory in spite of all terror! 
^Victory however long and hard the road may be! For without victory, 
^there is no survival. 
^You ask 'what is our policy?' I will say 'it is to wage war by sea, 
^land and air, with all our might, and with all the strength that God 
^can give us - to wage war against a monstrous tyranny never surpassed 
^in the dark and lamentable catalogue of human crime.' That is our policy." 
^ - Winston Churchill, May 13th 1940 
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Kobenhavn
attacker=Axis
defender=Allies
@THEN
TEXT
^The German ambassador von Renthe-Fink notified the Danish 
foreign minister that Denmark would either accept German occupation
or their capital, Copenhagen, would be bombed without mercy.  
Realizing that the tiny Danish army of 15,000 would be no match for the
mammoth German Wehrmacht, the Danes reluctantly give in without a
fight.  The decision was probably the right thing to do, because even
as the Danish king and his cabinet were discussing the ordeal, the
Germans had already docked at Copenhagen with an invasion force of 
1,000.
^The Danish invasion was extremely successful and before noon the 
Germans were using captured Danish airfields in their siege of Norway. 
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Oslo
attacker=Axis
defender=Allies
@THEN
TEXT
^Norwegian capital was taken by invading German troops. King Haakon VII 
escaped capture and managed to set up a government-in-exile in Britain.
An ambitious pro-Nazi Norwegian politician, Vidkun Quisling, helped Hitler 
with his invasion and proclaimed himself the new president.  
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Brussel
attacker=Axis
defender=Allies
@THEN
TEXT
^Belgium surrendered to Germany. King Leopold decided to stay in Belgia but 
government left to London.
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Amsterdam
attacker=Axis
defender=Allies
@THEN
TEXT
^Holland capitulates after brief struggle. Queen Wilhelmina and government were 
evacuated to London. 
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Abbeville
attacker=Axis
defender=France
@THEN
TEXT
^Wehrmacht tank divisions reached to sea under the command of general Guderian.
^Main French and British armies were cut off from their supply lines.
^Now it seemed clear that Battle of France would be won by Germany.
^  
^Paris was declared free city by French government in order to save its
^architecture.
ENDTEXT
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Paris
attacker=Axis
defender=France
@THEN
TEXT
^German armies entered to Paris! 
^The Fall of France was one of those bone-chilling events which mark the end of
^an era. France had been regarded as a major military power for three centuries.
^The victory in 1918 was supposed to have redeemed the disaster of 1870. 
^Yet the French army, with British and Polish support, was now knocked out by the 
^Nazi Wehrmacht in less time than Germany and Russia together had taken to knock
^out Poland. 1940 showed that 1870 was no aberration. 
ENDTEXT
PLAYWAVEFILE
THEME.WAV
JUSTONCE
@ENDIF

@IF
TURN
turn=5
@THEN
TEXT
^^JULY 1940
^Hitler is convinced that war in the West is won. He offer peace agreement 
^in conditions that Great Britain recognizes German hegemony in Continental 
^Europe and former German colonies are returned to her.
^Churchill reject the proposal and demand that Germany restores her borders 
^as they were in 1938. There are no negotiations and no compromise. 
^The War will go on.
ENDTEXT
@ENDIF

@IF
TURN
turn=7
@THEN
TEXT
^^SEPTEMBER 1940
^Tripartite (Axis) pact is signed by Germany, Italy and Japan. 
^In United States military conscription bill is passed.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=SS Panzers
attacker=ANYBODY
defender=Axis
@THEN
TEXT
SS division suffered heavy losses and was sent back to Germany to
refit and rest. 
ENDTEXT
CREATEUNIT
unit=SS Panzers
owner=Axis
veteran=yes
homecity=NONE
locations
65,65
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Polish Troops
attacker=ANYBODY
defender=Allies
@THEN
CREATEUNIT
unit=Polish Troops
owner=Allies
veteran=yes
homecity=NONE
locations
37,63
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Eben-Emael
attacker=Axis
defender=Allies
@THEN
TEXT
Germans captured Belgium fortress Eben-Emael!
ENDTEXT
@ENDIF

@IF
CITYTAKEN
city=USA and Canada
attacker=Axis
defender=Allies
@THEN
CREATEUNIT
unit=General
owner=Allies
veteran=yes
homecity=NONE
locations
0,32
endlocations
TEXT
Germany made surprise landing in North America! If germans manage save their
beachead then US and Canadian governments are forced to sign a peace treaty.  
ENDTEXT
PLAYWAVEFILE
AIRFORCE.WAV
@ENDIF

@IF
CITYTAKEN
city=LONDON
attacker=Axis
defender=Allies
@THEN
TEXT
^"We shall fight in France, we shall fight on the seas and oceans, 
^we shall fight with growing confidence and growing strength in the air. 
^We shall defend our island, whatever the cost may be. 
^We shall fight on the beaches, we shall fight on the landing grounds, 
^we shall fight in the fields and in the streets. We shall fight in the hills. 
^We shall never surrender!"
^ - Winston Churchill, June 4th 1940  
ENDTEXT
PLAYWAVEFILE
THEME.WAV
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Suez
attacker=Axis
defender=Allies
@THEN
TEXT
Rommel has reached his main goal: Suez canal is under Axis control! War in the 
Mediterranean Theatre is soon over.  
ENDTEXT
PLAYWAVEFILE
AIRFORCE.WAV
@ENDIF

@IF
CITYTAKEN
city=Roma
attacker=Allies
defender=Axis
@THEN
TEXT
^The Rome has fallen! The ultimate military defeat of Axis become closer and closer.
^
^"If you ask me, "Fhrer, how long will the war last?" I can only say as long as it
^takes to emerge victorious! Whatever may come! There is one word I will never know
^as leader of the German people and your Supreme Commander, it is "capitulation" 
^- that is, to submit to the will of another. Never, never! And you too have to think 
^like that."
^ - Adolf Hitler 
ENDTEXT
PLAYWAVEFILE
AIRFORCE.WAV
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=BERLIN
attacker=Allies
defender=Axis
@THEN
TEXT
After fierce fight Berlin has fallen!
ENDTEXT
PLAYWAVEFILE
THEME.WAV
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=60
receiver=Axis
@THEN
PLAYWAVEFILE
CAVALRY.WAV
MAKEAGGRESSION
who=Soviet Union 
whom=Axis
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Carrier
attacker=Axis
defender=Yugoslavia
@THEN
CREATEUNIT
unit=Light Tank
owner=Yugoslavia
veteran=yes
homecity=NONE
locations
79,91
74,92
67,85
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Marines
owner=Allies
veteran=yes
homecity=NONE
locations
2,32
endlocations
MOVEUNIT
unit=AnyUnit
owner=Allies
maprect
1,29,5,29,5,35,1,35
moveto
35,55
numbertomove=ALL
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Transport
owner=Allies
veteran=yes
homecity=NONE
locations
2,32
endlocations
@ENDIF

@IF
UNITKILLED
unit=Cruiser
attacker=Axis
defender=France
@THEN
TEXT
Germans captured a French cruiser!
ENDTEXT
CREATEUNIT
unit=Cruiser
owner=Axis
veteran=no
homecity=NONE
locations
58,56
endlocations
@ENDIF

@IF
UNITKILLED
unit=Battleship
attacker=Axis
defender=France
@THEN
TEXT
Germans captured a French battleship!
ENDTEXT
CREATEUNIT
unit=Battleship
owner=Axis
veteran=no
homecity=NONE
locations
58,56
endlocations
@ENDIF

@IF
TURNINTERVAL
interval=3
@THEN
CREATEUNIT
unit=M-11/39
owner=Axis
veteran=no
homecity=NONE
locations
60,98
endlocations
@ENDIF

@IF
UNITKILLED
unit=General
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
Famous general is killed!
ENDTEXT
CHANGEMONEY
receiver=TRIGGERDEFENDER
amount=-5000
PLAYWAVEFILE
THEME.WAV
@ENDIF

@ENDEVENTS
