@BEGINEVENTS

@IF
NOSCHISM
defender=ANYBODY
@THEN
@ENDIF

@IF
SCENARIOLOADED
@THEN
DONTPLAYWONDERS
@ENDIF

@IF
NEGOTIATION
talker=ANYBODY
talkertype=HumanOrComputer
listener=ANYBODY
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
UNITKILLED
unit=Freighter
attacker=Germans
defender=English
@THEN
CHANGEMONEY
receiver=English
amount=-100
@ENDIF

@IF
UNITKILLED
unit=Tanker
attacker=Germans
defender=English
@THEN
CHANGEMONEY
receiver=English
amount=-175
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Tanker
owner=English
veteran=no
homecity=NONE
locations
43,105
44,106
44,103
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Freighter
owner=English
veteran=no
homecity=NONE
locations
63,49
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Freighter
owner=English
veteran=no
homecity=NONE
locations
83,113
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Freighter
owner=English
veteran=yes
homecity=NONE
locations
45,57
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Freighter
owner=English
veteran=no
homecity=NONE
locations
66,32
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=12
@THEN
TEXT
On the June 22 the German Army invades the Soviet Union. The German Navy and Airforce 
launch attacks on the Soviet Navy.
ENDTEXT
MAKEAGGRESSION
who=Germans
whom=Soviets
@ENDIF

@IF
TURN
turn=19
@THEN
TEXT
On the 7th of December the Imperial Japanese Navy raids the US Pacific Fleet's main base at 
Pearl Harbour. 
In an act of solidarity with Japan Hitler declares war on the USA.
ENDTEXT
MAKEAGGRESSION
who=Germans
whom=Americans
@ENDIF

@IF
TURN
turn=19
@THEN
GIVETECHNOLOGY
receiver=Americans
technology=87
@ENDIF

@IF
TURN
turn=19
@THEN
GIVETECHNOLOGY
receiver=English
technology=87
@ENDIF

@IF
TURN
turn=19
@THEN
GIVETECHNOLOGY
receiver=Germans
technology=87
@ENDIF

@IF
UNITKILLED
unit=Bismarck Class
attacker=ANYBODY
defender=Germans
@THEN
TEXT
Following the loss of the Battleship Bismarck, Hitler orders the Kiegsmarine cease sending surface 
warships to raid Allied shipping. All construction of heavy warships is also canceled. 
ENDTEXT
CHANGEMONEY
receiver=TRIGGERATTACKER
amount=1000
JUSTONCE
GIVETECHNOLOGY
receiver=Germans
technology=80
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=RCN Corvette
owner=English
veteran=yes
homecity=NONE
locations
55,57
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=87
receiver=Americans
@THEN
CREATEUNIT
unit=Liberty Ship
owner=Americans
veteran=yes
homecity=NONE
locations
50,58
75,27
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=87
receiver=Americans
@THEN
CREATEUNIT
unit=Liberty Ship
owner=Americans
veteran=yes
homecity=NONE
locations
75,27
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=24
@THEN
TEXT
Japanese submarines comence operations against Allied shipping in the Indian Ocean.
ENDTEXT
CREATEUNIT
unit=Japanese Sub.
owner=Germans
veteran=yes
homecity=NONE
locations
157,117
155,117
157,110
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=9
@THEN
TEXT
The Lend Lease Bill is passed by the US Congress and is signed into law by President Roosevelt.
ENDTEXT
GIVETECHNOLOGY
receiver=English
technology=58
@ENDIF

@IF
TURN
turn=13
@THEN
TEXT
The United States takes over the defence of Iceland.
ENDTEXT
CREATEUNIT
unit=PBY-Catalina
owner=Americans
veteran=yes
homecity=NONE
locations
76,24
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=US Battleship
owner=Americans
veteran=yes
homecity=NONE
locations
82,18
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=13
@THEN
CREATEUNIT
unit=Fleet Destroyer
owner=Americans
veteran=yes
homecity=NONE
locations
82,18
82,16
82,14
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=15
@THEN
TEXT
At a meeting at Placentia Bay in Newfoundland President Roosevelt and Prime Minister Churchill 
sign the 'Atlantic Charter' onboard the British Battleship 'Prince of Wales'.
ENDTEXT
CREATEUNIT
unit=King George V
owner=English
veteran=yes
homecity=NONE
locations
50,50
48,50
50,52
52,50
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=16
@THEN
TEXT
The United States Navy begins escorting convoys in the Western Atlantic.
ENDTEXT
CREATEUNIT
unit=Fleet Destroyer
owner=Americans
veteran=yes
homecity=NONE
locations
50,56
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=27
@THEN
TEXT
The Navies of the United States and Japan fight the Battle of the Coral Sea, the first naval battle 
to be primarily fought by carrier launched aircraft. The battle ends with a strategic victory for the 
Americans.
ENDTEXT
@ENDIF

@IF
TURN
turn=28
@THEN
TEXT
The United States Navy smashes the Imperial Japanese navy at the Battle of Midway. Four 
Japanese Carriers were sunk by American Carrier aircraft. The Tide has turned against the 
Japanese.
ENDTEXT
CHANGEMONEY
receiver=Americans
amount=500
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=58
receiver=English
@THEN
CHANGEMONEY
receiver=English
amount=150
@ENDIF

@IF
TURN
turn=30
@THEN
TEXT
The German Army begins its attack on the Soviet city of Stalingrad.
ENDTEXT
@ENDIF

@IF
TURN
turn=33
@THEN
TEXT
November 1942 sees significant defeats for Germany. The 6th Army is trapped at Stalingrad by 
the Red Army,  The British Eighth Army, under General Montgomery crushes the German Afrika 
Korps at the Battle of El Alamein, and British and American troops invade North African in 
Operation TORCH.
ENDTEXT
@ENDIF

@IF
TURN
turn=35
@THEN
TEXT
The remnants of the German Sixth Army surrender at Stalingrad.
ENDTEXT
@ENDIF

@IF
TURN
turn=34
@THEN
TEXT
As part of the airlift being attempted to sustain German Forces at Stalingrad, all advailable 
Condor aircraft are sent to the Eastern Front to serve as cargo aircraft. If you are playing as the 
Germans send all your Condor Aircraft to Warsaw and keep them there untill March. (for added 
realism you should also disband a third of the planes!)
ENDTEXT
@ENDIF

@IF
TURN
turn=39
@THEN
TEXT
German and Italian forces in Tunisia surrender to the Allied Armies. 250,000 men are taken 
prisoner.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Training Range
attacker=Germans
defender=English
@THEN
CREATEUNIT
unit=Training Range
owner=English
veteran=yes
homecity=NONE
locations
120,24
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=23
@THEN
TEXT
As a result of heavy casualties from U-Boat attacks, the United States Navy belatedly begins 
convoy operations along the American East Coast.
ENDTEXT
GIVETECHNOLOGY
receiver=Americans
technology=16
@ENDIF

@IF
TURN
turn=20
@THEN
TEXT
Following the formal entry of the United States into the war Admiral Donitz launches Operation 
Drumbeat, the deployment of U-Boats along the East Coast of the United States. German 
Skippers find rich hunting, and label this period the 'second happy time' (the first having taken 
place in early 1940 in British home waters).
ENDTEXT
CREATEUNIT
unit=Type IX
owner=Germans
veteran=yes
homecity=NONE
locations
41,63
42,62
40,66
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=20
@THEN
CREATEUNIT
unit=Type IX
owner=Germans
veteran=yes
homecity=NONE
locations
35,75
35,77
35,73
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=20
@THEN
CREATEUNIT
unit=Type IX
owner=Germans
veteran=yes
homecity=NONE
locations
36,88
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
TURN
turn=-1
@THEN
MAKEAGGRESSION
who=Germans
whom=English
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=87
receiver=Germans
@THEN
MAKEAGGRESSION
who=Germans
whom=Americans
@ENDIF

@IF
TURN
turn=7
@THEN
TEXT
President Roosevelt is reelected to a record third term.
ENDTEXT
@ENDIF

@IF
TURN
turn=8
@THEN
TEXT
In a 'fireside chat' on the Lend Lease Bill that he his proposing, President Roosevelt calls for the 
United States to become the "arsenal of democracy". Opinion polls indicate that a majority of 
Americans support the Lend Lease Bill.
ENDTEXT
@ENDIF

@IF
TURN
turn=39
@THEN
TEXT
Historically Admiral Donitz recalled U-Boats from the North Atlantic this month due to the heavy 
casualties they had been taking. How are you going?
ENDTEXT
@ENDIF

@IF
TURN
turn=41
@THEN
TEXT
In the Mediterranean Alied troops land on Sicily, meanwhile on the Eastern Front the Battle of 
Kursk ends in defeat for the German Army.
ENDTEXT
@ENDIF

@IF
TURN
turn=43
@THEN
TEXT
Following the overthrow of Mussolini and the Allied Invasion of southern Italy, Italy surrenders. 
However, the German army occupies the country and the Italian campaign will drag on until 1945.
ENDTEXT
DESTROYACIVILIZATION
whom=Italian
@ENDIF

@IF
TURN
turn=46
@THEN
TEXT
In a meeting of the 'Big Three'  (Churchill, Roosevelt and Stalin) at Tehran, the Allies 
agree to launch a second front by the summer of 1944.
ENDTEXT
@ENDIF

@IF
TURN
turn=52
@THEN
TEXT
On the 6th of June 1944 Allied troops storm ashore along the coast of Normandy. Whilst the 
German submarine offencive will continue untill the last day of the war, its primary objective of 
preventing an Allied invasion of Europe has failed.
ENDTEXT
@ENDIF

@IF
TURN
turn=21
@THEN
TEXT
In Febuary 1942 the German U-boat command adopts a new and complex cypher, by adding a 
fourth  rotor to the enigma machines used in German Submarines. This change effectivly blinds the 
Allied code breakers who have previously been able to decode all messages sent using the three 
rotor enigma machine. 
(The Germans can now build the Shark Code wonder)
ENDTEXT
GIVETECHNOLOGY
receiver=Germans
technology=11
@ENDIF

@IF
TURN
turn=32
@THEN
TEXT
In December 1942 Allied code breakers at Bletchly Park finally break the 'Shark' code and 
resume reading signals sent to German submarines. (The Shark Code wonder is now obselete)
ENDTEXT
GIVETECHNOLOGY
receiver=English
technology=12
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=1
receiver=ANYBODY
@THEN
TEXT
The Allies begin the production of the B-24 Liberator. This aircraft, fitted with airborne radar and 
a powerful armament of depth charges and rockets, quickly establishes itself as the most sucessful 
anti-submarine aircraft in the Allies ever expanding arsenal.
ENDTEXT
JUSTONCE
GIVETECHNOLOGY
receiver=English
technology=1
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=87
receiver=Germans
@THEN
CREATEUNIT
unit=Type IX
owner=Germans
veteran=yes
homecity=NONE
locations
52,64
49,75
50,96
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
TEXT
British naval reinforcements arive in the Mediterranean
ENDTEXT
CREATEUNIT
unit=Battleship
owner=English
veteran=yes
homecity=NONE
locations
131,73
133,73
129,73
131,71
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
CREATEUNIT
unit=Type IX
owner=Germans
veteran=no
homecity=NONE
locations
57,85
57,87
57,89
57,83
59,83
55,83
0,0
0,0
0,0
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=10
@THEN
TEXT
Another German blockade runner arrives in the Atlantic.
ENDTEXT
CREATEUNIT
unit=Blockade Runner
owner=Germans
veteran=yes
homecity=NONE
locations
62,124
64,124
66,124
68,124
0,0
0,0
0,0
0,0
0,0
endlocations
CHANGEMONEY
receiver=Germans
amount=500
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=1
receiver=ANYBODY
@THEN
TEXT
To counter the growing threat from Allied aircraft, Donitz orders several submarines to be fitted 
out with an extra heavy anti-aircraft armament and be used to escort unmodified submarines 
through danger zones. Also, the Luftwaffe agrees to deploy some long ranged FW-190's to 
escort the submarines and Condors.
ENDTEXT
JUSTONCE
GIVETECHNOLOGY
receiver=Germans
technology=77
@ENDIF

@IF
RANDOMTURN
denominator=2
@THEN
CREATEUNIT
unit=Type VII
owner=Germans
veteran=no
homecity=NONE
locations
115,37
113,41
118,32
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
UNITKILLED
unit=Blockade Runner
attacker=ANYBODY
defender=Germans
@THEN
TEXT
Another blockade runner is intercepted at sea by Allied naval forces.
ENDTEXT
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=59
receiver=Germans
@THEN
TEXT
The Schnorchel is a tube which brings fresh air into submarines and allows them to operate thier 
engines while submerged, thereby greatly limiting thier vunerability to aircraft.
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=RCN Corvette
attacker=Germans
defender=English
@THEN
TEXT
The Royal Canadian Navy experianced the most dramatic growth of any of the worlds armed 
forces during the Second World War. Canada entered the war with just 6 naval vessels, and 
ended the war with an amazing 600! This huge force was almost exclusively employed in 
escorting convoys, with the RCN providing half of the Allies escort forces.
ENDTEXT
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Destroyer
attacker=Germans
defender=English
@THEN
TEXT
The Germans sink yet another British destroyer. During the early years of the war, these vital 
ships suffered near catastrophic losses, and by June 1940 the RN had only 74 operational 
destroyers advailable out of the pre-war fleet of 202 destroyers. 
With the shortage of destroyers greatly undermining Britains ability to escort convoys and attack 
the feared German invasion fleet, the British Government begins negotations with the United 
States in the hopes of aquiring some of the USN's mothballed WW1 era destroyers...
ENDTEXT
CHANGEMONEY
receiver=English
amount=-200
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=2
receiver=Americans
@THEN
CREATEUNIT
unit=LST
owner=Americans
veteran=yes
homecity=NONE
locations
36,68
31,75
51,53
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=6
@THEN
TEXT
Another German submarine arrives in the Mediterranean. However, passing through the Straits 
of Gibraltar continues to be costly.
ENDTEXT
CREATEUNIT
unit=Type VII
owner=Germans
veteran=yes
homecity=NONE
locations
122,60
122,64
115,59
113,55
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=3
@THEN
TEXT
German radar detects RAF bombers performing 'gardening' mine laying missions over the Baltic 
Sea.
ENDTEXT
CREATEUNIT
unit=Air Dropped Mine
owner=English
veteran=no
homecity=NONE
locations
109,35
110,36
115,37
118,32
112,38
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
UNITKILLED
unit=Destroyer
attacker=Germans
defender=English
@THEN
CREATEUNIT
unit=Old Destroyer
owner=English
veteran=yes
homecity=NONE
locations
41,61
49,53
47,61
39,79
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@IF
UNITKILLED
unit=New York City
attacker=Germans
defender=Americans
@THEN
TEXT
Upon hearing the news of the Kiegsmarine's bombardment of New York City Hitler authorises a 
dramatic expansion of the Kiegsmarine. Meanwhile, the American government belatedly improves 
New York's defences.
ENDTEXT
CREATEUNIT
unit=Coastal Battery
owner=Americans
veteran=yes
homecity=NONE
locations
34,62
0,0
0,0
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
CHANGEMONEY
receiver=Germans
amount=500
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=87
receiver=Americans
@THEN
CREATEUNIT
unit=Tanker
owner=Americans
veteran=yes
homecity=NONE
locations
18,86
18,88
18,82
0,0
0,0
0,0
0,0
0,0
0,0
endlocations
@ENDIF

@ENDEVENTS
